rule "Put Primo link temporary fields in 901"
priority 10
when
not exists "856.z.Link to Primo"
then
addField "901.{9,0}.a.https://exldeveu00.primo.exlibrisgroup.com/discovery/search?query=any,contains,"
addField "901.{9,1}.a.&tab=LibraryCatalog&search_scope=MyInstitution&vid=EXLDEV1_INST:Alma&lang=en&offset=0"
end


rule "Add system number 856.u from 001 prefixed by nothing"
priority 9
when
not exists "856.z.Link to Primo"
then
addSystemNumber "856.u" from "001" prefixed by "nothing"
prefixSubField "856.u" with "901.{9,0}.a"  if (not exists "856.u.*.*")
suffixSubField  "856.u" with "901.{9,1}.a" if (exists "856.u.*primo.exlibrisgroup.com*")
end



rule "Add 099 with conditions"
priority 8
when
  not exists "856.z.Link to Primo"
then
   addSubField "856.z.Link to Primo" if (exists "856.u.https://exldeveu00.primo.exlibrisgroup.com*")
end

rule "Fix indicators"
priority 7
when
  TRUE
then
changeFirstIndicator "856" to "4" if (exists "856.z.Link to Primo")
changeSecondIndicator "856" to "0" if (exists "856.z.Link to Primo")
end 


rule "Remove the 901 temporary fields"
priority 6
when
TRUE
then
removeField "901" if (exists "901.{9,0}.a.https://exldeveu00.primo.exlibrisgroup.com*")
removeField "901" if (exists "901.{9,1}.a.*&tab=LibraryCatalog*")
end